Add cmd installer entrypoint for Windows

2026-07-16 22:12:09 -04:00
parent 07879a1558
commit 1ca8a2e3ce
3 changed files with 52 additions and 0 deletions
@@ -0,0 +1,32 @@
+@echo off
+setlocal EnableExtensions
+
+set "SCRIPT_URL=%DOSH_INSTALL_PS1%"
+if "%SCRIPT_URL%"=="" set "SCRIPT_URL=https://git.palav.dev/Palav/dosh/raw/branch/main/install.ps1"
+
+set "PS="
+for %%P in (powershell.exe pwsh.exe powershell pwsh) do (
+    if not defined PS (
+        where %%P >nul 2>nul && set "PS=%%P"
+    )
+)
+
+if not defined PS (
+    echo missing required command: powershell.exe or pwsh.exe 1>&2
+    exit /b 1
+)
+
+set "TMP_PS=%TEMP%\dosh-install-%RANDOM%-%RANDOM%.ps1"
+set "DOSH_INSTALL_PS1_URL=%SCRIPT_URL%"
+set "DOSH_INSTALL_PS1_PATH=%TMP_PS%"
+
+"%PS%" -NoProfile -ExecutionPolicy Bypass -Command "$ErrorActionPreference='Stop'; $ProgressPreference='SilentlyContinue'; Invoke-WebRequest -UseBasicParsing -Uri $env:DOSH_INSTALL_PS1_URL -OutFile $env:DOSH_INSTALL_PS1_PATH"
+if errorlevel 1 (
+    del "%TMP_PS%" >nul 2>nul
+    exit /b 1
+)
+
+"%PS%" -NoProfile -ExecutionPolicy Bypass -File "%TMP_PS%" %*
+set "RC=%ERRORLEVEL%"
+del "%TMP_PS%" >nul 2>nul
+exit /b %RC%